Inside Macintosh: AppleScript Scripting Additions Guide /

Chapter 2 - Scripting Addition Commands / Command Definitions

/

Random Number

The Random Number command generates a random number. It is one of two commands provided by the Numerics scripting addition.

SYNTAX

random number                                         ¬
   [ numberToRandomize ]                              ¬
   [ from beginningNumber to endNumber ]              ¬
   [ with seed seedNumber ]

PARAMETERS

numberToRandomize

A number that specifies the upper limit of the range within which you want to generate a random number. If this number is a real value, the value returned is a real value; if this number is an integer value, the value returned is an integer.
Class: Real or integer

beginningNumber

A number that indicates the beginning of the range within which you want to generate a random number. If this number and endNumber are both integers, the value returned is an integer. If either this number or endNumber is a real value, the value returned is a real value.
Class: Real or integer

endNumber

A number that indicates the end of the range within which you want to generate a random number. If this number and beginningNumber are both integers, the value returned is an integer. If either this number or beginningNumber is a real value, the value returned is a real value.
Class: Real or integer

seedNumber

A number that specifies the number to use as the seed in generating a random number.
Class: Real or integer

RESULT

A random number within the specified limits. If no parameters are included, Random Number returns a real value between 0.0 and 1.0.

EXAMPLES

display dialog "A random number between 0 and 1: " & ¬
   (random number)

display dialog ¬
   "A random integer between 1 and 10: " & ¬
   (random number from 1 to 10)

display dialog ¬
   "A random real value between 1 and 10.0 : " & ¬
   (random number from 1 to 10.0)

display dialog ¬
   "A random real value between -10.0 and 10 : " & ¬
   (random number from -10.0 to 10)

display dialog ¬
   "A random integer between 1 and 10, 12 as seed: " & ¬
   (random number from 1 to 10 with seed 12)

After the seed is set, subsequent numbers generated by the Random Number command in the same script can be determined.

display dialog "This should be 9: " & ¬
   (random number from 1 to 10)

display dialog "This should be 1: " & ¬
   (random number from 1 to 10)

Reseeding with the value 0 causes the seed to be reset to a random value each time the command is called.

display dialog ¬
   "After reseeding with 0, a truly random number: " & ¬
   (random number from 1 to 10 with seed 0) 

ERRORS

Error number	Error message
-50	Parameter error.
-108	Out of memory.
-1700	Can't make some data into the expected type.
-1701	Some parameter is missing for <commandName>.
-1704	Some parameter was invalid.
-1705	Operation involving a list item failed.
-1708	<reference> doesn't understand the <commandName> message.
-1718	Reply has not yet arrived.